Consponsor2: Poisson Regession with Overdispersion

This model is Poisson regression of cosponsorships in all women's rights
legislation from the the 82nd to 102nd House of Representatives with a
Normal random effect to allow for overdispersion.  The covariates in the
model are the member's D-NOMINATE first dimension score (a measure of
conservatism), the party of the member (coded one for Democrats and zero
for Republicans), and the member's gender (coded one for women and zero
for men).   The data are discussed by Wolbrecht (2000).

model cosponsor2;
{
for (i in 1:N)
   {
   log(mu[i]) <-
     (beta[1] * cons[i] +
      beta[2] * dnom[i] + 
      beta[3] * party[i] + 
      beta[4] * gender[i] +
      lambda[i]) ;
   cospon[i] ~ dpois(mu[i]);
   lambda[i] ~ dnorm(0.0, tau);
   }

   # Priors
   for(j in 1:K)
      {
      beta[j] ~ dnorm(0.0, 0.0001);
      }
   tau ~ dgamma(0.001, 0.001);
   sigma2 <- 1/tau;

   # Posterior Predictive Distributions
   pred[1] <- exp(beta[1] + -0.627 * beta[2] + 0 * beta[3] + 1 * beta[4]);  # libRW
   pred[2] <- exp(beta[1] + -0.027 * beta[2] + 0 * beta[3] + 1 * beta[4]);  # modRW
   pred[3] <- exp(beta[1] +  0.573 * beta[2] + 0 * beta[3] + 1 * beta[4]);  # conRW
   pred[4] <- exp(beta[1] + -0.627 * beta[2] + 1 * beta[3] + 1 * beta[4]);  # libDW
   pred[5] <- exp(beta[1] + -0.027 * beta[2] + 1 * beta[3] + 1 * beta[4]);  # modDW
   pred[6] <- exp(beta[1] +  0.573 * beta[2] + 1 * beta[3] + 1 * beta[4]);  # conDW
   pred[7] <- exp(beta[1] + -0.627 * beta[2] + 0 * beta[3] + 0 * beta[4]);  # libRM
   pred[8] <- exp(beta[1] + -0.027 * beta[2] + 0 * beta[3] + 0 * beta[4]);  # modRM
   pred[9] <- exp(beta[1] +  0.573 * beta[2] + 0 * beta[3] + 0 * beta[4]);  # conRM
   pred[10] <- exp(beta[1] + -0.627 * beta[2] + 1 * beta[3] + 0 * beta[4]); # libDM
   pred[11] <- exp(beta[1] + -0.027 * beta[2] + 1 * beta[3] + 0 * beta[4]); # modDM
   pred[12] <- exp(beta[1] +  0.573 * beta[2] + 1 * beta[3] + 0 * beta[4]); # conDM

}